DESCRIPCIÓN

El escudo 2812 de Keyestudio, adopta el diseño apilable compatible con la tarjeta UNO R3. Es una fuente de luz LED de control inteligente que se integra al circuito de control y el chip RGB en un componente 5050 SMD. Incluye circuitos de puerto de datos digitales inteligentes y circuito de control de amplificación de señal de remodelación. También incluye un oscilador interno de precisión y una parte de control de corriente constante programable de 12V, garantizando efectivamente la alta consistencia del color de luz de punto de píxel.
El protocolo de transferencia de datos utiliza el modo de comunicación NZR único. Después del restablecimiento de encendido de píxeles, el puerto DI recibe datos del controlador, el primer píxel recolecta datos iniciales de 24 bits y luego se envía al cierre de datos interno.
LED con las ventajas del voltaje de conducción bajo, respetuoso del medio ambiente, ahorro de energía alto brillo, ángulo grande de la dispersión, buena consistencia, vida larga etc.

CARACTERÍSTICAS

• Circuito de protección anti-inversa, el reverso de la fuente de alimentación no dañará el IC interno del LED.
• El circuito de control del CI y la fuente de luz del punto del LED utilizan la misma fuente de alimentación.
• El circuito de control y el chip RGB están integrados en un componente 5050 SMD, formando un control completo del punto de pixel.
• Circuito de remodelación de señal incorporado, las señales recibidas se remodelarán primero y luego se enviarán al siguiente controlador, asegurando que la distorsión de forma de onda no se acumule.
• Potencia incorporada en el circuito de restablecimiento y en el circuito de reinicio de desconexión.
• Cada píxel de los tres colores primarios pueden alcanzar la exhibición de 256 brillo, completado 16777216 exhibición a todo color del color, frecuencia de la exploración no menos de 400Hz / s
• Interfaz en serie de la cascada, vía una línea de señal para terminar la recepción y la descodificación de datos.
• Cuando la distancia de transmisión entre dos puntos arbitrarios es de no más de cinco metros, no se necesita ningún circuito extra.
• Cuando la frecuencia de actualización es 30fps, el número de cascada no menos de 1024 puntos.
• La velocidad de envío de datos puede alcanzar 800Kbps.
• El color de la luz es altamente coherente, rentable.

VENTAJAS

1. El LED con el IC incorporado es más brillante que el LED común
2. Alta consistencia de chips RGB para todos los LEDs
3. Rendimiento confiable del IC incorporado del conductor
4. Utilice plástico duro para el embalaje, evite el daño de prensa

VISTA DEL ENSAMBLE CON UNO R3

CÓDIGO BÁSICO DE PRUEBA

#include <Adafruit_NeoPixel.h>

#ifdef __AVR__

#include <avr/power.h>

#endif

#define PIN 13

// Parameter 1 = number of pixels in strip

// Parameter 2 = Arduino pin number (most are valid)

// Parameter 3 = pixel type flags, add together as needed:

//   NEO_KHZ800  800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)

//   NEO_KHZ400  400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)

//   NEO_GRB     Pixels are wired for GRB bitstream (most NeoPixel products)

//   NEO_RGB     Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)

Adafruit_NeoPixel strip = Adafruit_NeoPixel(40, PIN, NEO_GRB + NEO_KHZ800);

// IMPORTANT: To reduce NeoPixel burnout risk, add 1000 uF capacitor across

// pixel power leads, add 300 - 500 Ohm resistor on first pixel's data input

// and minimize distance between Arduino and first pixel.  Avoid connecting

// on a live circuit...if you must, connect GND first.

void setup() {

 // This is for Trinket 5V 16MHz, you can remove these three lines if you are not using a Trinket

 #if defined (__AVR_ATtiny85__)

   if (F_CPU == 16000000) clock_prescale_set(clock_div_1);

 #endif

 // End of trinket special code

 strip.begin();

 strip.show(); // Initialize all pixels to 'off'

}

void loop() {

 // Some example procedures showing how to display to the pixels:

 colorWipe(strip.Color(255, 0, 0), 50); // Red

 colorWipe(strip.Color(0, 255, 0), 50); // Green

 colorWipe(strip.Color(0, 0, 255), 50); // Blue

 // Send a theater pixel chase in...

 theaterChase(strip.Color(127, 127, 127), 50); // White

 theaterChase(strip.Color(127, 0, 0), 50); // Red

 theaterChase(strip.Color(0, 0, 127), 50); // Blue

 rainbow(20);

 rainbowCycle(20);

 theaterChaseRainbow(50);

}

// Fill the dots one after the other with a color

void colorWipe(uint32_t c, uint8_t wait) {

 for(uint16_t i=0; i<strip.numPixels(); i++) {

   strip.setPixelColor(i, c);

   strip.show();

   delay(wait);

 }

}

void rainbow(uint8_t wait) {

 uint16_t i, j;

 for(j=0; j<256; j++) {

   for(i=0; i<strip.numPixels(); i++) {

     strip.setPixelColor(i, Wheel((i+j) & 255));

   }

   strip.show();

   delay(wait);

 }

}

// Slightly different, this makes the rainbow equally distributed throughout

void rainbowCycle(uint8_t wait) {

 uint16_t i, j;

 for(j=0; j<256*5; j++) { // 5 cycles of all colors on wheel

   for(i=0; i< strip.numPixels(); i++) {

     strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));

   }

   strip.show();

   delay(wait);

 }

}

//Theatre-style crawling lights.

void theaterChase(uint32_t c, uint8_t wait) {

 for (int j=0; j<10; j++) {  //do 10 cycles of chasing

   for (int q=0; q < 3; q++) {

     for (int i=0; i < strip.numPixels(); i=i+3) {

       strip.setPixelColor(i+q, c);    //turn every third pixel on

     }

     strip.show();

     delay(wait);

     for (int i=0; i < strip.numPixels(); i=i+3) {

       strip.setPixelColor(i+q, 0);        //turn every third pixel off

     }

   }

 }

}

//Theatre-style crawling lights with rainbow effect

void theaterChaseRainbow(uint8_t wait) {

 for (int j=0; j < 256; j++) {     // cycle all 256 colors in the wheel

   for (int q=0; q < 3; q++) {

     for (int i=0; i < strip.numPixels(); i=i+3) {

       strip.setPixelColor(i+q, Wheel( (i+j) % 255));    //turn every third pixel on

     }

     strip.show();

     delay(wait);

     for (int i=0; i < strip.numPixels(); i=i+3) {

       strip.setPixelColor(i+q, 0);        //turn every third pixel off

     }

   }

 }

}

// Input a value 0 to 255 to get a color value.

// The colours are a transition r - g - b - back to r.

uint32_t Wheel(byte WheelPos) {

 WheelPos = 255 - WheelPos;

 if(WheelPos < 85) {

   return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);

 }

 if(WheelPos < 170) {

   WheelPos -= 85;

   return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);

 }

 WheelPos -= 170;

 return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);

}

RESULTADO